Volledige voorbeeldprogramma’s

Programmeergidsen

Gegevens en functies

# taal: nl
laat spelers = [
    {"naam": "Ada", "score": 12},
    {"naam": "Pip", "score": 18},
    {"naam": "Mina", "score": 15},
]

functie beschrijf(speler):
    geef speler.naam + " scoorde " + tekst(speler.score)

laat besteIndex = 0
laat index = 1

zolang index < lengte(spelers):
    als spelers[index].score > spelers[besteIndex].score:
        zet besteIndex = index
    zet index = index + 1

voor speler in spelers:
    zeg beschrijf(speler)

zeg "Winnaar:", spelers[besteIndex].naam

Vragen stellen

# taal: nl
laat naam = vraag("Hoe heet je?")
laat niveau = vraagGetal("Kies een niveau van 1 tot 5", 1, 5)
laat thema = kies("Kies een thema", ["ruimte", "jungle", "racen"])
laat bevestigd = vraagJaNee("Nu beginnen?")

als bevestigd:
    zeg "Start", thema, "niveau", niveau, "voor", naam
anders:
    zeg "Instellen geannuleerd."
    sluitApp()

Coöperatieve grafische lus

# taal: nl
laat x = 300
laat y = 160
laat snelheid = 4

zolang waar:
    als toetsIngedrukt("left"):
        zet x = x - snelheid
    als toetsIngedrukt("right"):
        zet x = x + snelheid
    als toetsIngedrukt("up"):
        zet y = y - snelheid
    als toetsIngedrukt("down"):
        zet y = y + snelheid
    als toetsIngedrukt("space"):
        sluitApp()

    wisScherm("#0f172a")
    cirkel(x, y, 18, "#22d3ee")
    tekenTekst(320, 20, "Pijlen bewegen · Spatie sluit af", 20, "wit", "sans", "center")
    wacht(0.04)

3D-objecten met texturen en een camera

# taal: nl
wis3D("#16213e")
doos3D("krat", 1.5, 1.5, 1.5)
kleur3D("krat", "orange")
textuur3D("krat", "checker", 2)
draai3D("krat", 25)

cilinder3D("pilaar", 0.35, 2)
plaats3D("pilaar", 2, 0, 0)
kleur3D("pilaar", "blauw")
textuur3D("pilaar", "brick")

bol3D("bal", 0.5)
plaats3D("bal", -2, 0, 0)
kleur3D("bal", "rood")
stevig3D("bal", onwaar)

camera3D(0, 2, 6)
kijkNaar3D(0, 0, 0)
zeg "Krat raakt pilaar:", raakt3D("krat", "pilaar")
zeg "Gericht object:", richt3D(20)
teken3D()
tekenTekst(320, 20, "Mijn 3D-wereld", 24, "white", "sans", "center")

Patroonteksten en gemengde Engelse/Nederlandse kleurwaarden blijven behouden
bij syntaxisconversie. Bekijk ook
rotating-box.pliro en
laser-maze-3d.pliro.

Gerelateerde lemma’s

Syntaxis en waarden · Ingebouwde functies · Programmeergidsen